**3.21. Запрет редактирования реквизитов объектов**

Подсистема «Запрет редактирования реквизитов объектов» предназначена для запрета редактирования некоторых реквизитов объектов, которые определяют характер данного объекта и которые условно можно назвать ключевыми реквизитами данного объекта. Как правило, ключевыми реквизитами являются реквизиты объекта, влияющие на поведение других объектов, например на проведение документов. Необдуманное изменение таких реквизитов может привести к рассогласованию данных учета.

Примером может служить реквизит Валюта справочника Кассы, который определяет валюту остатков по данной кассе, или признак Является услугой справочника Номенклатура, который влияет на проведение документов с такой номенклатурой. Такие реквизиты нельзя изменять после появления остатков по данной кассе или после появления документов с данной номенклатурой соответственно.

При этом подсистема допускает программное изменение ключевых реквизитов объектов. В этом случае необходимые проверки должен выполнять вызывающий код.

**Настройка**

Для использования подсистемы необходимо выполнить следующие шаги:

1. Определить список объектов, для которых применяется подсистема, и состав их ключевых реквизитов (как минимум один реквизит для каждого объекта). Перечислить список этих объектов в процедуре ПриОпределенииОбъектовСЗаблокированнымиРеквизитами общего модуля ЗапретРедактированияРеквизитовОбъектовПереопределяемый.

// Определить объекты метаданных, в модулях менеджеров которых ограничивается возможность

// редактирования реквизитов с помощью экспортной функции ПолучитьБлокируемыеРеквизитыОбъекта.

//

// Функция ПолучитьБлокируемыеРеквизитыОбъекта должна возвращать значение Массив - строки в формате

// ИмяРеквизита[;ИмяЭлементаФормы,...], где ИмяРеквизита - имя реквизита объекта, ИмяЭлементаФормы -

// имя элемента формы, связанного с реквизитом. Например, "Объект.Автор", "ПолеАвтор".

//

// Поле надписи, связанное с реквизитом, не блокируется. Если требуется блокировать,

// имя элемента надписи нужно указать после точки с запятой, как написано выше.

//

// Параметры:

//   Объекты - Соответствие - в качестве ключа указать полное имя объекта метаданных,

//             подключенного к подсистеме "Запрет редактирования реквизитов объектов",

//             в качестве значения - пустую строку.

//

// Пример:

//   Объекты.Вставить(Метаданные.Документы.ЗаказПокупателя.ПолноеИмя(), "");

//

//   При этом в модуле менеджера документа ЗаказПокупателя размещается код:

//   // См. ЗапретРедактированияРеквизитовОбъектовПереопределяемый.ПриОпределенииОбъектовСЗаблокированнымиРеквизитами.

//   Функция ПолучитьБлокируемыеРеквизитыОбъекта() Экспорт

//    БлокируемыеРеквизиты = Новый Массив;

//    БлокируемыеРеквизиты.Добавить("Организация"); // заблокировать редактирование реквизита Организация

//    Возврат БлокируемыеРеквизиты;

//   КонецФункции

//

Процедура ПриОпределенииОбъектовСЗаблокированнымиРеквизитами(Объекты) Экспорт

2. Принять решение по поводу состава объектов метаданных, наличие ссылок из которых на данный объект метаданных не должно влиять на возможность редактирования его ключевых реквизитов. Такие объекты следует включить в фильтр поиска исключений ссылок (см. раздел «[Настройка исключений поиска ссылок на объекты](https://its.1c.ru/db/content/bsp301doc/src/3.4.%20базовая%20функциональность.htm?_=1542292879#_настройка_исключений_поиска)»).

Для каждого объекта метаданных, для которого применяется подсистема, надо выполнить следующие шаги:

1. Добавить в модуль менеджера объекта функцию ПолучитьБлокируемыеРеквизитыОбъекта, в которой вернуть список имен ключевых реквизитов/табличных частей объекта или реквизитов формы. После имени реквизита можно указать точку с запятой и через запятую перечислить имена дополнительных элементов формы, имеющих отношение к реквизиту, которые тоже нужно заблокировать:

// См. ЗапретРедактированияРеквизитовОбъектовПереопределяемый.ПриОпределенииОбъектовСЗаблокированнымиРеквизитами.

Функция ПолучитьБлокируемыеРеквизитыОбъекта() Экспорт

Результат = Новый Массив;

Результат.Добавить("ИмяРеквизитаОбъекта1");

Результат.Добавить("ИмяТабличнойЧастиОбъекта1");

Результат.Добавить("ИмяРеквизитаФормы1");

Результат.Добавить("ИмяРеквизитаОбъекта2; ИмяЭлементаФормы1, ИмяЭлементаФормы2");

...

Возврат Результат;

КонецФункции

Поле надписи, связанное с реквизитом, не блокируется. Если требуется блокировать, имя элемента поля надписи нужно указать после точки с запятой, как написано выше.

2. Добавить в модуль формы объекта процедуру:

&НаКлиенте

Процедура Подключаемый\_РазрешитьРедактированиеРеквизитовОбъекта(Команда)

ЗапретРедактированияРеквизитовОбъектовКлиент.РазрешитьРедактированиеРеквизитовОбъекта(ЭтотОбъект);

КонецПроцедуры

3. Добавить в обработчики событий ПриСозданииНаСервере и ПослеЗаписиНаСервере код:

// Обработчик подсистемы запрета редактирования реквизитов объектов

ЗапретРедактированияРеквизитовОбъектов.ЗаблокироватьРеквизиты(ЭтотОбъект);

Примечание

Вторым параметром функции может выступать группа формы, на которую будет прикреплена команда разрешения редактирования ключевых реквизитов.

4. Для ключевых реквизитов в свойствах объекта рекомендуется выставлять свойство Проверка заполнения как Выдавать ошибку либо вручную осуществлять проверку ключевых реквизитов на заполненность.

Пример использования подсистемы можно посмотреть в демонстрационной конфигурации в справочнике \_ДемоНоменклатура.

**Переопределение логики, разрешающей изменение ключевых реквизитов**

Существует возможность задать нестандартные условия разрешения изменения ключевых реквизитов. Для этого нужно сделать следующее.

Во-первых, переопределить содержимое процедуры модуля формы объекта Подключаемый\_РазрешитьРедактированиеРеквизитовОбъекта. Пример:

&НаКлиенте

Процедура Подключаемый\_РазрешитьРедактированиеРеквизитовОбъекта(Команда)

ЗаблокированныеРеквизиты = ЗапретРедактированияРеквизитовОбъектовКлиент.Реквизиты(ЭтотОбъект);

Если ЗаблокированныеРеквизиты.Количество() > 0 Тогда

ПараметрыФормы = Новый Структура;

ПараметрыФормы.Вставить("Ссылка", Объект.Ссылка);

ПараметрыФормы.Вставить("ЗаблокированныеРеквизиты", ЗаблокированныеРеквизиты);

ОткрытьФорму("Документ.\_ДемоЗаказПокупателя.Форма.РазблокированиеРеквизитов", ПараметрыФормы,

ЭтотОбъект,,,, Новый ОписаниеОповещения("ПослеВыбораРеквизитовДляРазблокирования", ЭтотОбъект));

Иначе

ЗапретРедактированияРеквизитовОбъектовКлиент.ПоказатьПредупреждениеВсеВидимыеРеквизитыРазблокированы();

КонецЕсли;

КонецПроцедуры

&НаКлиенте

Процедура ПослеВыбораРеквизитовДляРазблокирования(РазблокируемыеРеквизиты, Контекст) Экспорт

Если ТипЗнч(РазблокируемыеРеквизиты) <> Тип("Массив") Тогда

Возврат;

КонецЕсли;

ЗапретРедактированияРеквизитовОбъектовКлиент.УстановитьДоступностьЭлементовФормы(ЭтотОбъект,

РазблокируемыеРеквизиты);

КонецПроцедуры

Во-вторых, создать свою форму РазблокированиеРеквизитов. В ней позволить пользователю пометить нужные реквизиты и вернуть результат с помощью метода Закрыть. Пример:

&НаКлиенте

Процедура РазрешитьРедактирование(Команда)

РазблокируемыеРеквизиты = Новый Массив;

РазблокируемыеРеквизиты.Добавить("<Имя реквизита>");

…

Закрыть(РазблокируемыеРеквизиты);

КонецПроцедуры

В случаях, когда необходимо самостоятельно рассчитывать и устанавливать значения свойств ТолькоПросмотр или Доступность соответствующих полей разблокируемых реквизитов с учетом разных причин, вместо процедуры УстановитьДоступностьЭлементовФормы нужно вызвать процедуру УстановитьРазрешенностьРедактированияРеквизитов. Она не изменяет доступность полей реквизитов, а только отмечает реквизиты как разрешенные для редактирования, что нужно для корректной работы функции Реквизиты. Кроме того, если какие-то из реквизитов нужно считать недоступными для разблокировки, например, если для реквизита формы нет права редактирования, заданного через роли, или по другой причине, можно переопределить значение свойства ПравоРедактирования с помощью процедуры УстановитьРазрешенностьРедактированияРеквизитов. Это необходимо для корректного отключения доступности команды разблокировки реквизитов, когда все реквизиты уже разблокированы.

Форму, которая будет разрешать редактирование реквизитов, следует назвать РазблокированиеРеквизитов, чтобы поддержать групповое изменение объектов информационной базы. Форма должна возвращать массив, содержащий имена реквизитов, которые нужно разблокировать. Для возврата массива следует использовать метод Закрыть. Кроме того, если форма обслуживает более одного реквизита, то рекомендуется использовать параметр формы ЗаблокированныеРеквизиты, в который передается Массив имен реквизитов для разблокирования.

**Размещение в командном интерфейсе**

Все действия по изменению командного интерфейса выполняются при интеграции подсистемы (см. выше).

**Настройка прав доступа пользователей**

Для настройки прав доступа пользователей к данным подсистемы «Запрет редактирования реквизитов объектов» следует использовать роль, указанную ниже.

Таблица 3.40.

| № | Роли и их назначение |
| --- | --- |
| 1. | РедактированиеРеквизитовОбъектов  Редактирование заблокированных значений реквизитов объектов |

Пример настройки прав доступа пользователей приведен ниже.

Таблица 3.41.

| № | Группа пользователей и ее функции | Состав ролей |
| --- | --- | --- |
| 1. | Ответственный за ведение документов | <ДобавлениеИзменениеДокументов> – основная роль, предоставляющая право редактирования документа.  РедактированиеРеквизитовОбъектов |

**Использование при разработке конфигурации**

**Настройка обмена данными**

Для настройки обмена данными никаких действий не требуется, так как подсистема не предоставляет собственных данных.